제 능력만으로 만든건 아니고 여기저기 검색해서 스크립트 짜집어봤어요

그중에는 클리앙의 HYM님 게시물도 참고했습니다!

하지만 HYM님의 캡스락+단축키 와는 작동방식을 다르게 했어요

제가 자주 쓰는것만 모아봤습니다.

; # win

; ! alt

; ^ ctrl

; + shift

; * 상용구 바로 입력

; ? 상용구 입력된 문자에 상관없이 입력

SetCapsLockState, AlwaysOff  ;  캡스락 키의 기본이벤트를 작동하지 않게함

#If GetKeyState("Capslock","P")  ; P면 누르고있을때1 뗏을때 0 , T면  캡스 토글on시 1 off시 0 // 토글의경우 alwaysoff를 쓰지않아야함

    t:: run "C:\Program Files (x86)\Naver\Naver Whale\Application\whale.exe" https://keep.google.com/u/0/    

    e:: OpenWindowTitle("Visual Studio Code", "C:\Users\Administrator\AppData\Local\Programs\Microsoft VS Code\Code.exe") 

    w:: OpenWindowTitle("Simplenote", "C:\Program Files\Simplenote\Simplenote.exe")

    r:: OpenWindowTitle("카카오톡", "C:\Program Files (x86)\Kakao\KakaoTalk\KakaoTalk.exe")

; 위 4가지는 각각 프로그램 실행,최소화 단축키와 연결

    ; 이 밑으로는  캡스와 같이 누를시 작동하는 단축키들

    i::Up

    j::Left

    k::Down

    l::Right

    n::BackSpace

    m::Delete

    u::Home

    o::End

    a::MouseClick

    s:: MouseClick,R

    d:: WheelUp

    x:: WheelDown

    +z::CapsLock

    +q:: 

    MouseGetPos, vx,vy

    msgbox,%vx% %vy%

    return

    q::MouseClick,left,%vx%,%vy%

#If ; 캡스 누르면 작동하는 단축키목록 끝

#e:: ; 윈도우키+e를 누르면 edit창을 실행후 저장, 만약 이미 실행해있을경우 활성화 후 저장 (edit과 reload를 합친것)

ifwinexist a.ahk - SciTE4AutoHotkey 

{ 

winactivate 

send ^s  

reload 

} 

else 

{ 

edit

sleep 500 

send ^s 

reload 

} 

return 

#r:: keyhistory ; keyhistory 열기

;------------------------------------------------------------

;기본상용구

:*?:cnost::const

:*?:cosnt::const

:*?:porps::props

:*?:->::→

:*?:<-::←

;-----------------------------------------------------------

; 프로그램 실행,최소화 단축키  ( 프로그램을 실행, 만약 이미 실행해있을시 활성화, 한번 더누르면 최소화)

OpenWindowTitle(WindowTitleWord, AppAddress){

    SetTitleMatchMode, 2     

    IfWinExist, %WindowTitleWord%

    {    

        IfWinActive

        {

            WinMinimize

            Return

        }

        else

        {

            WinActivate

            Return

        }    

    }

    else

    {

        Run, %AppAddress%, UseErrorLevel

        If ErrorLevel

        {

            Msgbox, File %AppAddress% Not Found

            Return

        }

        else

        {

            WinActivate

            Return

        }

    }

}